One Hat Cyber Team

Your IP: 216.73.216.93
Server IP: 65.108.141.171
Server: Linux server.heloix.com 5.4.0-214-generic #234-Ubuntu SMP Fri Mar 14 23:50:27 UTC 2025 x86_64
Server Software: Apache
PHP Version: 7.4.33
Buat File | Buat Folder

Dir : ~/usr/share/webmin/virtual-server/

Edit File: list-ports.pl

#!/usr/bin/perl

=head1 list-ports.pl

Lists TCP ports associated with some virtual server

This command lists all TCP ports in use by or allowed to be used by the
virtual server selected with the C<--domain> flag. To output a list of just
port numbers, use the C<--port-only> flag. Or to show the full details of
each port, use C<--multiline>.

=cut

package virtual_server;
if (!$module_name) {
	$main::no_acl_check++;
	$ENV{'WEBMIN_CONFIG'} ||= "/etc/webmin";
	$ENV{'WEBMIN_VAR'} ||= "/var/webmin";
	if ($0 =~ /^(.*)\/[^\/]+$/) {
		chdir($pwd = $1);
		}
	else {
		chop($pwd = `pwd`);
		}
	$0 = "$pwd/list-ports.pl";
	require './virtual-server-lib.pl';
	$< == 0 || die "list-ports.pl must be run as root";
	}

# Parse command-line args
while(@ARGV > 0) {
	local $a = shift(@ARGV);
	if ($a eq "--domain") {
		$domain = shift(@ARGV);
		}
	elsif ($a eq "--multiline") {
		$multi = 1;
		}
	elsif ($a eq "--port-only") {
		$portonly = 1;
		}
	elsif ($a eq "--help") {
		&usage();
		}
	else {
		&usage("Unknown parameter $a");
		}
	}

$domain || &usage("No domain specified");
$d = &get_domain_by("dom", $domain);
$d || usage("Virtual server $domain does not exist");

my @useports = &active_domain_server_ports($d);
my @canports = &allowed_domain_server_ports($d);
my @allports = sort { $a->{'lport'} <=> $b->{'lport'} } (@useports, @canports);

my %done;
if ($multi) {
	# Show full details
	foreach my $p (@allports) {
		next if ($done{$p->{'lport'}}++);
		print $p->{'lport'},"\n";
		my ($use) = grep { $_->{'lport'} eq $p->{'lport'} } @useports;
		my ($can) = grep { $_->{'lport'} eq $p->{'lport'} } @canports;
		print "  In use: ",($use ? "Yes" : "No"),"\n";
		print "  Allowed: ",($can ? "Yes" : "No"),"\n";
		if ($use) {
			print "  Used by PID: ",$use->{'proc'}->{'pid'},"\n";
			print "  Used by command: ",$use->{'proc'}->{'args'},"\n";
			print "  Used by user: ",$use->{'user'}->{'user'},"\n";
			}
		if ($can) {
			print "  Allowed type: ",$can->{'type'},"\n";
			print "  Allowed by: ",$can->{'desc'},"\n";
			}
		}
	}
elsif ($portonly) {
	# Just show port numbers
	foreach my $p (&unique(map { $_->{'lport'} } @allports)) {
		print $p,"\n";
		}
	}
else {
	# Show table of ports
	$fmt = "%-6.6s %-10.10s %-6.6s %-50.50s\n";
	printf $fmt, "Port", "Status", "PID", "Allowed by";
	printf $fmt, ("-" x 6), ("-" x 10), ("-" x 6), ("-" x 50);
	foreach my $p (@allports) {
		next if ($done{$p->{'lport'}}++);
		my ($use) = grep { $_->{'lport'} eq $p->{'lport'} } @useports;
		my ($can) = grep { $_->{'lport'} eq $p->{'lport'} } @canports;
		printf $fmt, $p->{'lport'},
			$use && $can ? "Active" :
			$can ? "Allowed" :
			$use ? "Not allowed" : "",
			$use ? $use->{'proc'}->{'pid'} : "",
			$can ? $can->{'desc'} : "";
		}
	}

sub usage
{
print "$_[0]\n\n" if ($_[0]);
print "Lists TCP ports associated with some virtual server.\n";
print "\n";
print "virtualmin list-ports --domain name\n";
print "                     [--multiline]\n";
print "                     [--port-only]\n";
exit(1);
}